doc for 迴圈

for 迴圈

批次檔的 for 迴圈很重要，但有些特性比較隱晦，不容易駕馭，下面稍加整理需注意使用之處
  1. for 迴圈初始化變數，在撰寫為批次檔時，請使用 %%variable，而在命令列執行時要改用 %variable。
  2. for 迴圈初始化變數有大小寫的區分，所以 %%i 不同於 %%I。
  3. for 迴圈內的變數會有取值異常的情形。
以下針對第3點取值異常的情形作一說明，迴圈的敘述通常是以下列格式撰寫，左括弧與 do 同一行，右括弧放在最後面獨立成行
for %%i in (*) do (
    echo %%i
    timeout 1
)
但其實批次檔會把迴圈內的敘述集結成一行變成
for %%i in (*) DO echo %%i & timeout 1
但就因為集結成一行的關係，批次檔在命令解譯器進行直譯時，會對每一行敘述中的變數進行預先賦值的動作，因此會造成同一行敘述中，對變數改變其值卻無效的情形，請猜一下底下這個範例會顯示的值是甚麼?
@echo off 
set var=Peter
set var=John & echo %var% 
timeout 6
結果仍是 Peter ，因為針對第3行，命令解譯器會預先賦值給%var%，然後才進行 set var = John，若要正確取出此變數異動後的值 John ，必須 啟用變數延遲展開(SETLOCAL ENABLEDELAYEDEXPANSION)的功能，在開啟用變數延遲展開功能之後，取用變數的方式要由 %var% 更改為 !var!，將範例修改如下
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set var=Peter
set var=John & echo !var!
timeout 6
批次檔中只要是利用括弧()分成多行撰寫的指令，實際上都看成一行，在括弧()裡面取用變數時都會遇到需要開啟用延遲環境變數擴充功能的問題，一定要特別注意。
以下直接說明範例不特別解釋語法，細節請透過 for /? 學習

找出符合條件之檔案的 for 迴圈

  1. 顯示批次檔存在的目錄中所有符合.mp4 .avi *.mpg的檔案名稱
    for %%i in (*.mp4 *.avi *.mpg) DO @echo %%i
  2. 顯示使用者目錄中的所有檔案名稱 此例必須直接在命令列輸入(注意變數名稱的差別)、環境變數 userprofile 代表使用者目錄
    for %i in (%userprofile%\*) DO @echo %i

找出符合條件之目錄的 for /D 迴圈

  • 顯示使用者目錄中的所有目錄名稱 此例必須直接在命令列輸入(注意變數名稱的差別)、環境變數 userprofile 代表使用者目錄
    for /D %i in (%userprofile%\*) DO @echo %i

遞迴搜尋指定的路徑下所有符合檔案的 for /R 迴圈

  • 將 c:\temp\ 目錄與所有子目錄下的 *.bak 刪除
    for /R c:\temp\ %%G in (*.bak) do del "%%G"

可以設定開始數值、增/減數值、停止數值的 for /L 迴圈

  1. 顯示 0-100 的數字 (從0開始、遞增1、終止值100)
    for /L %%i in (0 1 100) do echo %%i
  2. 計算從1累加至100的和
    set sum=0  
for /L %%i IN (100, -1, 1) DO set /a sum+=%%i 
echo %sum%
  3. 啟用延遲環境變數擴充功能範例
    SETLOCAL ENABLEDELAYEDEXPANSION 
for /L %%i in (1 1 5) do (
set var=%%i
echo !var!
)
timeout 6

逐行讀取文字檔的 for /F 迴圈

for /F 是迴圈中最重要的應用，因為它可以讀取檔案、讀取字串與讀取命令，分別說明如下：
  1. 讀取檔案：逐行讀取指定的檔案，然後依照分隔符號將內容賦值給指定變數
    範例：逐行讀取 test.ini 文字檔內容，以等號(=)為分隔，左邊給%%i，右邊給%%j
    FOR /F "tokens=1,2 delims==" %%i IN (test.ini) DO set %%i=%%j
    test.ini 內容如下
    account=john
passwd=a1234567890
    上述指令執行完畢之後會有下列效果， 將原來必須放在批次檔內部的變數設定，放在外部的 ini 檔之後進行讀取，將程式碼與設定檔分離，可減少原始檔被亂改的機會
    set account=john
set passwd=a1234567890
  2. 讀取字串：讀取字串或變數，然後依照分隔符號將內容賦值給指定變數
    範例：讀取變數%date%, 以斜線(/)為分隔，依序給%%a、%%b、%%c三變數，再依照年/月/日的格式，儲存到mydate變數
    For /f "tokens=1-3 delims=/ " %%a in ("%date%") do set mydate=%%a/%%b/%%c
  3. 讀取命令：依照分隔符號將內容賦值給指定變數
    命令執行的結果，成為 for /F 迴圈讀取資料的來源，須注意此命令須包含在單引號之間， 若命令中包含了管線 | ，則須在管線前方加上逸脫字元 ^
    範例1：將命令 date /t 的執行結果, 以斜線(/)為分隔，依序給%%a、%%b、%%c三變數，輸出年-月-日的格式
    for /F "tokens=1-3 delims=/ " %%a in ('date /t') do echo %%a-%%b-%%c
    範例2：將命令 sc query 的執行結果透過管線輸出給 find 指令，尋找包含有SERVICE_NAME字串的列，然後將第2欄的內容存到 %i 變數並顯示出來
    rem 此例必須直接在命令列輸入(注意變數名稱的差別)
for /f "tokens=2" %i in ('sc query ^| find /i "SERVICE_NAME"') do @echo %i
    sc query 命令會顯示目前系統所有的服務
    範例3：利用 findstr 過濾文字檔(.csv)包含有井字號(#)的列,然後 以逗號(,)為分隔，依序給%%I、%%J、%%K、%%L 4變數，然後再分別設定到有意義的變數中儲存
    rem 設定參數檔名與批次檔相同(.csv)
set cfg=%~n0.csv
FOR /F "tokens=1,2,3,4 delims=," %%I IN ('findstr /V [#] %cfg%') DO (
 set remoteDIR=%%I
 set localBackupFolder=%%J
 set RetentionDay=%%K
 set isCallCheckspace=%%L
)
    與批次檔同名的csv檔，其內容如下
    #遠端備份名稱,本地端備份路徑,備份保留天數,是否檢查硬碟剩餘空間
myweb,C:\backup,20,Y

留言

張貼留言

這個網誌中的熱門文章

格式透視 - 解析 PE 文件格式

圖片
程式身家基本訊息：PE file structure PE 是 Portable Executable 的縮寫，也就是 Windows 系統中的可執行（Executable）程式或動態連結函式庫（Dynamic link library）的文件格式，主要使用在 32 位和 64 位的 Windows 操作系统上。 為了能夠瞭解 PE 格式，我們需要以下的對照： 1. PE 格式示意圖 2. Hiew 程式，以小算盤為範例 3. PE 格式圖 以下為簡單對照 DOS MZ Header 開頭必定為＂MZ＂4D 5A，這是 DOS EXE 的 Signature。而這東西讓 PE file 在 DOS 模式下也可執行，所佔大小為 40h bytes。 DOS Stub 但也不是什麼都能在 DOS 底下執行，若是程式在 DOS 下無法執行便會跳出這邊的錯誤訊息：＂ This Program cannot be run in DOS mode ＂。 PE Header 為了找到 PE 的開頭位置，我們可從 DOS Header 0x3C 的位置找到一個 Double word（又稱 dword，大小為 4 個 bytes），這個 dword 大小表示了整個 DOS MZ Header 的 size， 也就是 D8 00 00 00 ，注意！這裡實際位置是 0x000000D8 ，想必 IQ180 的各位已經注意到必須以 Byte 為單位顛倒過來看才行，這種反向讀取方式稱之為 Little－endian order ，在 PE 文件中皆採用此種讀取方式。 到了 PE 位置所看到的必定是 50 45，PE Header 裡包含了許許多多的訊息，其中最重要之一就是距離 PE 位置（0xD8）後 0x28 的 dword，這裡是這隻程式執行時的入口點（Entry point）。聽起來好像沒什麼重要的，不過若是入口點被設置在檔案的 Overlay 區域呢？這就很有趣了～正常來說是不會設置在這邊的。 什麼是 Overlay? 這個以後會再說 再往後數 12 Bytes 則是 Image base，下圖最後 4 Bytes，也就是 0x01000000 之前找到的入口點是相對虛擬位置（Relative virt
閱讀完整內容

doc call呼叫外部程式與副程式

呼叫外部程式與副程式 常用的呼叫外部程式有下列幾種方式 call 外部程式 從批次檔中呼叫外部程式並可傳遞參數，在同一個 shell 環境下，可共同存取相同的環境變數。 rem test.cmd @echo off call test1.cmd hello pause rem test1.cmd @echo off echo %1 timeout 6 cmd /c 外部指令 呼叫一個新的shell程式(cmd)並於指令執行完成後結束這個 shell ，返回原來的shell環境，外部程式執行在新的shell之中，因此存取的環境變數與原程式不同，有區域變數的遮蔽效果 @echo off cmd /c notepad.exe exit 留意上述範例執行情形，在notepad.exe關閉以前，不會執行 exit 指令，因為指令尚未結束，還留在新的shell當中。 開始一個新視窗執行程式 => start [program] [parameters] 因為 cmd /c 具有同步特性(會等外部程式執行完畢)，因此不太適合呼叫需與使用者互動的視窗程式，因為命令提示視窗會因等待而保持開啟，所以適合改用 start 來呼叫執行。 @echo off start notepad.exe exit 使用 /wait 也可以改讓 start 具有同步特性，詳情參考 start /? 副程式呼叫 批次檔的副程式呼叫也是利用 call 指令，不同的是 call 的對象不是外部程式 ，而是相同檔案中的標籤，也可以傳遞參數。 因為批次檔的副程式僅利用標籤代表區塊的開始，因此副程式都放在程式的尾部，之後就不要寫任何命令敘述了，代表區塊的結束。 因為批次檔循序讀取的特性，就算副程式沒有被呼叫，也會被當作標籤一般順序執行下來，因此在副程式之前通常要加上 goto :EOF 強制結束批次檔。 call :標籤 參數1 參數2... @echo off rem for迴圈使用方式請參考本手冊相關章節 for %%i in (*.dll *.exe) DO CALL :SubRoutin "%%i" pause goto :EOF :SubRoutin echo %1, %~n1, %~x1
閱讀完整內容